DevMagazin/三角関数

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16

/* HSP開発Wiki sin,cos サンプルコード */
    screen 0, 400, 400
    radian = 0.00
*main
    radian += 0.05
    redraw 0
    color 255, 255, 255 : boxf
    color
    line 200, 400, 200, 0
    line 400, 200, 0, 200
    // (200, 200)を中心に、半径100の円を描いて運動します
    pos 200 + cos(radian)*100, 200 - sin(radian)*100
    mes "●"
    redraw 1
    wait 4
    goto *main

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14

    radian = 0.0 : dosuu = 0 : objsize 100
    pos   0, 0 : input radian
    pos 100, 0 : button gosub "ラジアンで指定", *btnRadian
    pos 250, 0 : input dosuu
    pos 350, 0 : button gosub "度数で指定", *btnDosuu
    stop
 
*btnRadian
    line 640, 480-tan(double(radian))*640, 0, 480
    return
 
*btnDosuu
    line 640, 480-tan(double(dosuu)*3.14/180)*640, 0, 480
    return

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51

; atanサンプルコード
; Y軸が鉛直下方向に正であることに注意！
 
    cx = ginfo_winx / 2         ; 画面の中心(center)のX座標
    cy = ginfo_winy / 2         ; 画面の中心(center)のY座標
    pi = 3.14159265             ; 円周率π(pi) atan(1) * 4 としても良い
 
*main
    redraw 1 : await 16 : redraw 0 : color 255, 255, 255 : boxf : color : pos 0,0
 
    ; 座標取得
    px = mousex
    py = mousey
 
    ; 計算処理
    dx = px - cx                ; cx,cyを中心とした相対座標(dx, dy)を計算
    dy = py - cy
    rad = atan(dy, dx)          ; x軸との角度を計算(-π〜+πの値が返ってきます)
    deg = rad * 180.0 / pi      ; 度に換算
 
    ; 0〜360度になるよう計算
    rad2 = rad
    if rad2 < 0.0 : rad2 += pi * 2
    deg2 = rad2 * 180.0 / pi
 
    ; 計算結果表示
    pos 0,0 : color
    mes "atan(" + dy + " / " + dx + ")"
    mes "= " + deg + " 度"
    mes "= " + rad + " rad"
 
    mes "以下は0〜360度になるよう計算したもの。"
    mes "= " + deg2 + " 度"
    mes "= " + rad2 + " rad"
 
    ; 図表示
    line ginfo_winx, cy, 0, cy
    line ginfo_winx, cy, ginfo_winx - 20, cy - 20
    line ginfo_winx, cy, ginfo_winx - 20, cy + 20
    pos ginfo_winx - 30, cy : mes "x"
 
    line cx, ginfo_winy, cx, 0
    line cx, ginfo_winy, cx - 20, ginfo_winy - 20
    line cx, ginfo_winy, cx + 20, ginfo_winy - 20
    pos cx + 5, ginfo_winy - 30 : mes "y"
 
    pos cx + 5, cy : mes "o"
    color 255, 0, 0
    line cx, cy, px, py
 
    goto *main

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94

 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
-
|
-
|
|
!
|
!
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 

    #define PI 3.14159265
    #define P2 6.28318520
    px=300                      // 星の中心X
    py=250                      // 星の中心Y
    hosi=5                      // 星の角の数
    size1=75                    // 中心から星の凹の長さ
    size2=150                   // 中心から星の凸の長さ
    speed=0.0                   // 星の回転速度
    scale=1.0                   // 表示倍率　1.0 = 100%
    rad_hosi1=P2/hosi           // 星の凸から凸までのラジアン
    rad_hosi2=PI/hosi           // 星の凸から凹までのラジアン
    kaiten=PI/2                 // 星の向きのラジアン
 
*main
    redraw 0
    gosub *drag
    gosub *draw
    gosub *msg
    redraw 1
    await 17
    goto *main
 
*drag
    stick key,256+512
//*//右クリックドラッグ（↑↓）でズーム
    my2=my1
    my1=mousey
    if key&512    :zoom=0.0+my2-my1     // 前回と今のマウスＹから拡大値を求める
/*///右クリックドラッグ（近づくと拡大、離れると縮小）でズーム
    zm2=zm1
    zm1=sqrt((mousex-px)*(mousex-px)+(mousey-py)*(mousey-py))
    if key&512    :zoom=zm2-zm1         // 前回と今のマウスＹから拡大値を求める
//*/
    zoom*0.9                            // 摩擦
    scale+=0.004*zoom                   // 拡大の変化を大人しくする
    scale1=scale*size1                  // 星の凸の大きさ
    scale2=scale*size2                  // 星の凹の大きさ
 
    //左クリックドラッグで回転
    atan2=atan1
    atan1=atan(mousex-px,mousey-py)
 
    if key&256 {
        //ラジアンが一周して値が飛ぶのを考慮
        if absf(atan1-atan2)>PI    {
            if (atan1<0)&(atan2>=0)    :atan2-=P2
            if (atan1>=0)&(atan2<0)    :atan2+=P2
        }
        speed=(atan2+P2)-(atan1+P2)     // 前回のatanと今のatanから回転値を求める
    }
 
    speed*=0.95*(absf(speed)>0.0001)    // 摩擦
    kaiten+=speed                       // 星の向きに計算した回転値を加算
 
    // 回転のラジアンの範囲を0〜2πに閉じ込める
    if kaiten<0        :kaiten=kaiten-int(kaiten/P2)*P2+P2
    if kaiten>P2    :kaiten=kaiten-double(int(kaiten/P2))*P2
    return
 
*draw
    color 255,255,255    :boxf
    color    :pset px,py
    
    // circle px-scale1,py-scale1,px+scale1,py+scale1,0
    // circle px-scale2,py-scale2,px+scale2,py+scale2,0
 
    // ☆描画
    // 一回のループで1つの∠を描画、hosi 回繰り返して星１個
    repeat hosi
        x1=cos(rad_hosi1*cnt+kaiten)*scale1              // トゲ描き始めX
        y1=sin(rad_hosi1*cnt+kaiten)*scale1              // トゲ描き始めY
        x2=cos(rad_hosi1*cnt+rad_hosi2+kaiten)*scale2    // トゲの先端X
        y2=sin(rad_hosi1*cnt+rad_hosi2+kaiten)*scale2    // トゲの先端Y
        x3=cos(rad_hosi1*(cnt+1)+kaiten)*scale1          // トゲ描き終わりX
        y3=sin(rad_hosi1*(cnt+1)+kaiten)*scale1          // トゲ描き終わりY
        line px+x1,py+y1,px+x2,py+y2
        line px+x3,py+y3,px+x2,py+y2
        pset px+x1,py+y1                                 // １ドット空くのを補完
    loop
    return
 
*msg
    pos 0,0
    mes "kaiten :"+kaiten
    mes "zoom :"+zoom
    mes "x1 :"+x1
    mes "y1 :"+y1
    mes "scale :"+scale
    mes "scale1 :"+scale1
    mes "scale2 :"+scale2
    mes "atan1 :"+atan1
    mes "atan2 :"+atan2
    mes "speed :"+speed
    return

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20

;指定された角度を-180〜180度の範囲内の値に変換します。
#module
#defcfunc deglimit double deg
    a = deg - 360*(deg / 360)
    return a - 360*(a / 180)
#global
 
;実行サンプル
;キーボードの↑↓を押してください。
*main
    redraw 1 : await 16 : redraw 0 : color 255, 255, 255 : boxf : color : pos 0,0
    stick key, 15
 
    if key & 2 : a++
    if key & 8 : a--
 
    mes a
    mes deglimit(a)
 
    goto *main